SkyGridX Installation Guide for Minecraft 1.21.6 (Java 21)

Quick Setup (Lazy Install)

If you'd prefer an automated process, you can use the install.bat script. This script will:

• Create the required folder (plugins).
• Download and place the latest version of the plugin (from this repo).
• Download and place the latest Paper server JAR.
• Automatically sign the eula.txt.
• Generate a run.bat file with default memory settings: -Xms1G -Xmx4G.

Steps:

1. Download the install.bat script

@echo off
setlocal

:: CONFIG
set plugin_url=https://raw.githubusercontent.com/DavidS-Repo/SkyGridx/main/SkyGrid-1.21.6.jar
set run_bat_url=https://raw.githubusercontent.com/DavidS-Repo/SkyGridx/main/run.bat
set paper_fetch_url=https://www.davids-repo.dev/fetch_latest_paper_build/

set plugin_folder=plugins

:: Create folders (suppress errors if they already exist)
mkdir "%plugin_folder%" 2>nul

:: Fetch latest PaperMC URL...
echo Fetching latest PaperMC URL...
for /f "usebackq tokens=*" %%A in (`curl -s "%paper_fetch_url%"`) do set paper_url=%%A

if not defined paper_url (
  echo ERROR: Could not fetch PaperMC URL.
  exit /b 1
)

:: Extract filename from URL
for %%F in ("%paper_url%") do set paper_file=%%~nxF

:: Download Paper server jar under its real name
echo Downloading Paper jar as "%paper_file%"...
curl -L -o "%paper_file%" "%paper_url%"

:: Download SkyGridX plugin
echo Downloading plugin...
curl -L -o "%plugin_folder%\SkyGrid.jar" "%plugin_url%"

:: Create and sign EULA with timestamp
for /f "tokens=1-4 delims=/ " %%a in ('date /t') do set today=%%c-%%a-%%b
for /f "tokens=1-2 delims=:"   %%a in ('time /t') do set time=%%a:%%b
set datetime=%today% %time%

(
  echo # By changing the setting below to TRUE you are indicating your agreement to our EULA ^(https://aka.ms/MinecraftEULA^).
  echo #%datetime%
  echo eula=true
) > eula.txt

:: Download your run.bat
echo Downloading run.bat...
curl -L -o run.bat "%run_bat_url%"

:: All set -- launch!
echo Setup complete. Starting server...
call run.bat

endlocal

2. Place the script in your server directory.
3. Run the script by double-clicking it.
4. Use the generated run.bat to start the server in the future.

Note:

• You can adjust the memory allocation (-Xms1G -Xmx4G) in the run.bat file.
• If it’s just for you, your server address is localhost; no port forwarding needed.

Manual Setup

For those who prefer full control over the installation, follow the steps below:

1. Prepare Server Launch

1. Create a .bat file and paste the following commands to initialize the server:

@echo off
for %%f in (*.jar) do set JAR=%%f
REM Launching Java with Aikar's flags
java ^
 -Xms1G ^
 -Xmx4G ^
 -XX:+UseG1GC ^
 -XX:+UnlockExperimentalVMOptions ^
 -XX:G1NewSizePercent=30 ^
 -XX:G1MaxNewSizePercent=40 ^
 -XX:G1HeapRegionSize=8M ^
 -XX:G1ReservePercent=20 ^
 -XX:G1HeapWastePercent=5 ^
 -XX:G1MixedGCCountTarget=4 ^
 -XX:InitiatingHeapOccupancyPercent=15 ^
 -XX:G1MixedGCLiveThresholdPercent=90 ^
 -XX:G1RSetUpdatingPauseTimePercent=5 ^
 -XX:SurvivorRatio=32 ^
 -XX:+PerfDisableSharedMem ^
 -XX:MaxTenuringThreshold=1 ^
 -XX:+OptimizeStringConcat ^
 -XX:+UseCompressedOops ^
 -XX:+DisableExplicitGC ^
 -XX:+AlwaysPreTouch ^
 -XX:+ParallelRefProcEnabled ^
 -XX:+UseNUMA ^
 -XX:ParallelGCThreads=16 ^
 -XX:ConcGCThreads=16 ^
 -XX:MaxGCPauseMillis=50 ^
 -Dusing.aikars.flags=https://mcflags.emc.gs ^
 -Daikars.new.flags=true ^
 -jar "%JAR%" --nogui
pause

2. Download and place your prefered server.jar in the same folder

3. Save and run the .bat to initialize the server.

2. Sign the EULA

1. After running the .bat, open eula.txt.
2. Change eula=false to eula=true and save.

Do not restart the server yet. Continue to the next step.

3. Plugin Setup

1. Download the latest SkyGridX plugin JAR from this repo.

2. Place the downloaded .jar file into the plugins folder.

4. Server Launch

1. Run run.bat (either the one you generated or your custom one).
2. Wait for the console to show the server is ready.

Look for:
[INFO]: Chunks have been loaded. You can now connect!

Additional Notes

• Use a Bukkit-compatible server (Paper or Purpur recommended).
• For issues or feature requests, visit the Discord.

Manual Setup (Folia)

1. Prepare Server Launch

1. Create a .bat file and paste the following commands to initialize the server:

@echo off
for %%f in (*.jar) do set JAR=%%f
REM Launching Java with Aikar's flags
java ^
 -Xms1G ^
 -Xmx4G ^
 -XX:+UseG1GC ^
 -XX:+UnlockExperimentalVMOptions ^
 -XX:G1NewSizePercent=30 ^
 -XX:G1MaxNewSizePercent=40 ^
 -XX:G1HeapRegionSize=8M ^
 -XX:G1ReservePercent=20 ^
 -XX:G1HeapWastePercent=5 ^
 -XX:G1MixedGCCountTarget=4 ^
 -XX:InitiatingHeapOccupancyPercent=15 ^
 -XX:G1MixedGCLiveThresholdPercent=90 ^
 -XX:G1RSetUpdatingPauseTimePercent=5 ^
 -XX:SurvivorRatio=32 ^
 -XX:+PerfDisableSharedMem ^
 -XX:MaxTenuringThreshold=1 ^
 -XX:+OptimizeStringConcat ^
 -XX:+UseCompressedOops ^
 -XX:+DisableExplicitGC ^
 -XX:+AlwaysPreTouch ^
 -XX:+ParallelRefProcEnabled ^
 -XX:+UseNUMA ^
 -XX:ParallelGCThreads=16 ^
 -XX:ConcGCThreads=16 ^
 -XX:MaxGCPauseMillis=50 ^
 -Dusing.aikars.flags=https://mcflags.emc.gs ^
 -Daikars.new.flags=true ^
 -jar "%JAR%" --nogui
pause

2. Download and place your prefered server.jar in the same folder

   

3. Save the .bat file and run it to initialize the server.

   

2. Sign the EULA

1. After running the .bat file, locate and open the eula.txt file in the server directory.

2. Change eula=false to eula=true and save the file.

   

Do not restart the server yet. Continue with the next steps.

3. Download and Set Up Plugin & Datapack

Plugin Setup

1. Download the latest Folia version of the SkyGridX plugin from the repo.

2. Place the downloaded .jar file into the plugins folder of your server.

   
   

Datapack Setup

1. In the server directory, create a folder named world.

2. Inside the world folder, create a folder named datapacks.

3. Choose and download one of the following datapacks:

   • Option 1: Skyblock Void Worldgen
     • Features: Biome data, structure bounding boxes, and some structures.
     • Performance Impact: Higher server load due to additional data and features.
     • Download Link: Skyblock Void Worldgen
   • Option 2: Void-Biomes-1.21.5.zip
     • Features: Lightweight alternative with only biome data and the End dragon structure (portal and pillars).
     • Performance Impact: Lower server load.
     • Download Link: Void-Biomes-1.21.5.zip

4. Place the downloaded datapack into the datapacks folder.

Important: Make sure the datapack is placed in the folder before starting the server to correctly generate the world.

4. Server Launch & World Generation

1. Re-run the .bat file to start the server and generate the necessary files.

2. Monitor the console output and wait for messages indicating the server is ready.

3. Be patient during world generation, as it may take some time depending on your datapack choice.

   

5. Enjoy the SkyGrid World

1. Connect to your server to explore your custom SkyGrid world.

2. Verify successful setup with a console message: [INFO]: Chunks have been loaded. You can now connect!

   

Additional Notes

• The SkyGrid plugin requires a Bukkit or Spigot-based server; for optimal performance use Paper or Purpur servers.
• For issues or feature requests, visit the discord.